【讨论】(关于分数的问题)消化吸收现有资料，提出问题讨论

分数不是目的，关键是大家大增功力！
1）讨论问题解答问题比做题目的用处大的多！
2）CAE技术涉及的东西太多，关键能用于实际工作中
  
今天整理了一下资料，发现不少，我基本没有时间看过，
我觉得大家光收集资料意义不大，不如针对其中自己不理解的，或者有自己见解的，拿出来讨论，一样可以加分的（虽然加分不是目的）

强烈支持，多讨论大家分析之中遇到的问题

正在考虑变截面梁的问题，正好也在分析这个算例。用shell单元没什么好说的。对于用beam44单元，它只是准确定义了平面内的抗弯刚度，对于梁在片面内的宽度并没有按实际情况取为了1。这在仅考虑弯曲变形的情况下是可以的。如果想准确定义实际的宽度，好象还是有点麻烦，因为j点到上表面的厚度是根据i点来定义的，见附图。好象还有点麻烦，应该有办法的，正在考虑中。

命令流：
  
/COM,ANSYS MEDIA REL. 7.1 (03-13-2003) REF. VERIF. MANUAL: REL. 7.1
/VERIFY,VM34
/PREP7
/TITLE, VM34, BENDING OF A TAPERED PLATE (BEAM)
!        INTROD. TO STRESS ANALYSIS, HARRIS, 1ST PRINTING, PAGE 114, PROB. 61
!        PLATE ELEMENTS (SHELL63)
ANTYPE,STATIC               ! STATIC ANALYSIS
ET,1,SHELL63,2
R,1,.5                      ! THICKNESS = 0.5
MP,EX,1,30E6
MP,NUXY,1,0                 ! POISSON'S RATIO IS ZERO
N,1
N,8,20,-1.5
FILL
N,11
N,18,20,1.5
FILL
E,1,2,12
E,2,3,12
E,13,12,3
E,3,4,14
E,14,13,3
EGEN,3,2,2,5
CP,1,UZ,2,12                ! COUPLE APPROPRIATE DEGREES OF FREEDOM
CP,2,ROTY,2,12
CPSGEN,6,1,1,2              ! GENERATE 6 SETS OF EQUATIONS
OUTPR,ALL,ALL
D,8,ALL,,,18,10
D, ALL,ROTX,0               ! REMOVE "TORSIONAL" DEGREES OF FREEDOM
F,1,FZ,-10
FINISH
/SOLU     
SOLVE
FINISH
/POST1
ETABLE,STRS,S,1             ! STORE S1(TOP) FOR SHELL63
ESORT,STRS                  ! SORT ELEMENTS BASED ON S1(TOP)
*GET,SMAX,SORT,,MAX         ! GET MAXIMUM S1 AS SMAX
PRNSOL,DOF                  ! PRINT NODAL DISPLACEMENTS
LFT_NODE = NODE (0,0,0)
*GET,DEFL,NODE,LFT_NODE,U,Z
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
LABEL(1,1) = 'DEFLECTI','MX_PRIN_'
LABEL(1,2) = 'ON (in) ','STRS psi'
*VFILL,VALUE_C1(1,1),DATA,-.042667,1600
*VFILL,VALUE_C1(1,2),DATA,DEFL,SMAX
*VFILL,VALUE_C1(1,3),DATA,ABS(DEFL/.042667 ) ,ABS( SMAX/1600 )
SAVE,TABLE_1
FINISH
/CLEAR, NOSTART  
/PREP7
/TITLE, VM34, BENDING OF A TAPERED PLATE (BEAM)
!              TAPERED BEAM ELEMENTS (BEAM44)
ANTYPE,STATIC               ! STATIC ANALYSIS
ET,1,BEAM44
*DO,I,1,10                  ! CREATE DO LOOP FOR REAL CONSTANTS
  R,I,  1,1,.003125*(I-1),.25,1      
  RMORE,1,1,.003125* I   ,.25,1
*ENDDO
RMOD,1,3,.5E-3              !  GIVE FREE END A POSITIVE MOMENT OF INERTIA
RLIST
MP,EX,1,30E6
MP,GXY,1,30E6/2.6
N,1
N,11,20
FILL
N,12,,,1                    ! NODE 12 FOR ALIGNING BEAM AXES
NGEN,10,1,12                ! NODES 12 TO 21 ARE COINCIDENT
E,1,2,12
EGEN,10,1,1,,,,,1           ! GENERATE ELEMENTS WITH REAL CONSTANT INCREASED BY 1
D,11,ALL
D,1,UY,,,10,,ROTX,ROTZ
F,1,FZ,-10
OUTPR,ALL,ALL
FINISH
/SOLU     
SOLVE
FINISH
/POST1
ETABLE,STRS,NMISC,1         ! STORE SMAX (MAXIMUM STRESS) FOR BEAM44
ESORT,STRS                  ! SORT ELEMENTS BASED ON SMAX (MAXIMUM STRESS)
*GET,SMAX,SORT,,MAX         ! GET MAXIMUM STRESS AS SMAX
PRNSOL,DOF                  ! PRINT NODAL DISPLACEMENTS
LFT_NODE = NODE (0,0,0)
*GET,DEFL,NODE,LFT_NODE,U,Z
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C2,,2,3
LABEL(1,1) = 'DEFLECTI','MX_PRIN_'
LABEL(1,2) = 'ON (in) ','STRS psi'
*VFILL,VALUE_C2(1,1),DATA,-.042667,1600
*VFILL,VALUE_C2(1,2),DATA,DEFL,SMAX
*VFILL,VALUE_C2(1,3),DATA,ABS(DEFL/.042667 ) ,ABS( SMAX/1600 )
SAVE,TABLE_2
RESUME,TABLE_1
/COM
/OUT,vm34,vrt
/COM,------------------- VM34 RESULTS COMPARISON ---------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM,RESULTS USING SHELL63:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,'   ',F12.6,'  ',F12.6,'   ',1F5.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,'   ',F12.6,'  ',F12.6,'   ',1F5.3)
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST,vm34,vrt

示意图：

没用过这个单元，看看这个例子如何？来自校验手册
Test Case
A tapered cantilever plate of rectangular cross-section is subjected to a load F at its tip. Find the maximum deflection δ and the maximum principal stress σ1 in the plate.
  
Figure 34.1. Beam Problem Sketch
  
Material Properties  
E = 30 x 106 psi  
υ = 0.0  
  Geometric Properties  
L = 20 in  
d = 3 in  
t = 0.5 in  
  Loading  
F = 10 lbs  
   
  
Analysis Assumptions and Modeling Notes
The problem is solved first using quadrilateral shell elements (SHELL63) and then using tapered beam elements (BEAM44). For the quadrilateral shell elements (used in triangular form), nodal coupling is used to ensure symmetry. For the beam elements, the area and Y dimension of the beam are not used and are input as 1.0. Node 12 is arbitrarily located at Z = 1.0 in order to define the orientation of the beam.
  
Results Comparison
  Target ANSYS Ratio  
SHELL63 Deflection, in -0.042667

斑竹高见~::y::y::g
  
交流才能提高~8D
  
一直没于太多时间弄，现在还停留在模仿操作阶段，
  
对一些命令还不是很熟悉，理解也不深刻，
  
有点感受就是有限元理论知识还是得知道一些，
  
否则理解起来真费劲，正看一些书ing~:I
  
昨天练习遇到一问题，给beam加载加不上，说没有定义单元，
可是我有定义单元类型啊 beam tapered 44 (3d)::l
不知道咋回事::l:-d

同意版主的意见!
CAE技术涉及的东西太多，而且需要深厚的力学基础,我认为大家如能把自己平时解决实际的问题做为教程或实例贴出,供其他人解决其他类似问题也很有意义.