关于UG中的KF模块

#! UG/KF 17.0
#
  
DefClass: ug_edge_blend_example (ug_base_part);
  
#+
     Create a block and apply a blend to its edges.
     To be used with a new metric part.
#-
  
(Number Parameter) Radius: 1.0;
  
(Child) Block: {
   Class;    ug_block;
   Height;    10;
   Length;    10;
   Width;    10;
};
  
(Child) Blend: {
   Class;      ug_edge_blend;
   Edge_Blend_References;  ug_body_askEdges(Block: );
   Radius;      Radius:;
};

多谢！！！

Edge_Blend_References;  ug_body_askEdges(Block: );  
以上那句不解，倒角倒的是所有的边，能实现只倒个别的几个指定的边么，具体的语句有事怎么样的呢？请赐教

：（
完全不懂
：（

能阿,换个函数就行了

怎么换啊 请frecar明示 谢谢了！

函数ug_body_askEdgeClosestToPoint(Any $body, Point $point)
其中$body是边所在的实体
      $point可以是你所要得到的边上的一点.
如果你选的是几条边共点的那一点,那么将得到那几条边的一个LIST

请问frecar兄，如同ug_body_askEdgeClosestToPoint(Any $body, Point $point)这一类的函数的介绍和用法在哪本书里能学习到，ug的doc里面有么，我现在要用到大量这方面的东东，真不好意思一而再再而三的麻烦你啊^_^

帮助文档中都有说明的.

我看到一个dfa文件，楼主能否帮着分析以下，特别是（child）后面的%是什么意思？？？？？
  
#! UG/KF 17.0
  
DefClass: nut (ug_base_part);
    (number parameter) bolt_diameter:1.0;
    (number parameter) hex_height:0.5;
    (point  parameter) position:point(0,0,0);
    (vector parameter) x_direction:vector(1,0,0);
    (vector parameter) y_direction:vector(0,1,0);
  
    (number) hex_flat_width: 1.75*bolt_diameter:;
    (number) radius: hex_flat_width: / 2.0 / cos(30.0);
    (vector) z_direction: x_direction: * y_direction:;
  
    (child list) %lines: {
            class; ug_line;
            start_point; position: + radius:*cos(60*(child:index:-1))*x_direction: +
                                     radius:*sin(60*(child:index:-1))*y_direction:;
            end_point; position: + radius:*cos(60*child:index*x_direction: +
                                   radius:*sin(60*child:index*y_direction:;
            suppress?; true;
            quantity; 6;
    };
  
    (child) %extrusion: {
            class; ug_extruded;
            profile; %lines:;
            end_limit; hex_height:;
            direction; -1 * z_direction:;
    };
  
    (child) %upper_cone: {
            class; ug_cone;
            base_diameter; hex_flat_width: + (2*hex_height:/tan(30));
            top_diameter; 0;
            height; hex_height: + hex_flat_width: * tan(30)/2;
            origin; position:;
            direction; -1 * z_direction:;
    };
  
    (child) %lower_cone: {
            class; ug_cone;
            base_diameter; hex_flat_width: + (2*hex_height:/tan(30));
            top_diameter; 0;
            height; hex_height: + hex_flat_width: * tan(30)/2;
            origin; position: + -1*hex_height:*z_direction:;
            direction; z_direction:;
    };
  
    (child) %hole: {
            class; ug_cylinder;
            diameter; bolt_diameter:;
            height; hex_height:;
            origin; position:;
            direction; -1 * z_direction:;
    };
  
   (child) %bool1: {
            class; ug_boolean;
            operation; intersect;
            tool; {%upper_cone:};
            target; {%extrusion:};
    };
  
    (child) %bool2: {
            class; ug_boolean;
            operation; intersect;
            tool; {%lower_cone:};
            target; {%bool1:};
    };
  
    (child) %bool3: {
            class; ug_boolean;
            operation; subtract;
            tool; {%hole:};
            target; {%bool2:};
    };
  
    (child) %body: {
            class; ug_body;
            feature; {%bool3:};
            color; 4;
    };